Sync inav to Gitea

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/collect.cmake

@@ -0,0 +1,40 @@
+function (collector_create name base)
+  set_property (GLOBAL PROPERTY "COLLECT_${name}_LIST")
+  set_property (GLOBAL PROPERTY "COLLECT_${name}_BASE" "${base}")
+endfunction (collector_create)
+
+function (collector_list var name)
+  get_property (_list GLOBAL PROPERTY "COLLECT_${name}_LIST")
+  set (${var} "${_list}" PARENT_SCOPE)
+endfunction (collector_list)
+
+function (collector_base var name)
+  get_property (_base GLOBAL PROPERTY "COLLECT_${name}_BASE")
+  set (${var} "${_base}" PARENT_SCOPE)
+endfunction (collector_base)
+
+function (collect name)
+  collector_base (_base ${name})
+  string(COMPARE NOTEQUAL "${_base}" "" _is_rel)
+  set (_list)
+  foreach (s IN LISTS ARGN)
+    if (_is_rel)
+      get_filename_component (s "${s}" ABSOLUTE)
+      file (RELATIVE_PATH s "${_base}" "${s}")
+    else (_is_rel)
+       get_filename_component (ts "${s}" ABSOLUTE)
+       if (EXISTS "${ts}")
+         set (s "${ts}")
+       endif (EXISTS "${ts}")
+    endif (_is_rel)
+    list (APPEND _list "${s}")
+  endforeach ()
+  set_property (GLOBAL APPEND PROPERTY "COLLECT_${name}_LIST" "${_list}")
+endfunction (collect)
+
+# Create global collectors
+collector_create (PROJECT_INC_DIRS    "")
+collector_create (PROJECT_LIB_DIRS    "")
+collector_create (PROJECT_LIB_DEPS    "")
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/depends.cmake

@@ -0,0 +1,23 @@
+if (WITH_LIBMETAL_FIND)
+  find_package (Libmetal REQUIRED)
+  collect (PROJECT_INC_DIRS "${LIBMETAL_INCLUDE_DIR}")
+  collect (PROJECT_LIB_DIRS "${LIBMETAL_LIB_DIR}")
+  collect (PROJECT_LIB_DEPS "${LIBMETAL_LIB}")
+endif (WITH_LIBMETAL_FIND)
+
+if ("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
+  check_include_files (stdatomic.h HAVE_STDATOMIC_H)
+  check_include_files (fcntl.h HAVE_FCNTL_H)
+else ("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
+  set (_saved_cmake_required_flags ${CMAKE_REQUIRED_FLAGS})
+  set (CMAKE_REQUIRED_FLAGS "-c")
+  check_include_files (stdatomic.h HAVE_STDATOMIC_H)
+  check_include_files (fcntl.h HAVE_FCNTL_H)
+  set (CMAKE_REQUIRED_FLAGS ${_saved_cmake_required_flags})
+endif ("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
+
+if (NOT HAVE_FCNTL_H)
+  unset (WITH_PROXY CACHE)
+endif (NOT HAVE_FCNTL_H)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/modules/FindLibmetal.cmake

@@ -0,0 +1,31 @@
+# FindLibmetal
+# --------
+#
+# Find Libmetal
+#
+# Find the native Libmetal includes and library this module defines
+#
+# ::
+#
+#   LIBMETAL_INCLUDE_DIR, where to find metal/sysfs.h, etc.
+#   LIBSYSFS_LIB_DIR, where to find libmetal library.
+
+# FIX ME, CMAKE_FIND_ROOT_PATH doesn't work
+# even use the following
+# set (CMAKE_FIND_ROOT_PATH_MODE_LIBRARY BOTH)
+# set (CMAKE_FIND_ROOT_PATH_MODE_INCLUDE BOTH)
+# set (CMAKE_FIND_ROOT_PATH_MODE_PROGRAM BOTH)
+find_path(LIBMETAL_INCLUDE_DIR NAMES metal/sys.h PATHS ${CMAKE_FIND_ROOT_PATH})
+find_library(LIBMETAL_LIB NAMES metal PATHS ${CMAKE_FIND_ROOT_PATH})
+get_filename_component(LIBMETAL_LIB_DIR ${LIBMETAL_LIB} DIRECTORY)
+
+# handle the QUIETLY and REQUIRED arguments and set HUGETLBFS_FOUND to TRUE if
+# all listed variables are TRUE
+include (FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS (LIBMETAL DEFAULT_MSG LIBMETAL_LIB LIBMETAL_INCLUDE_DIR)
+
+if (LIBMETAL_FOUND)
+  set (LIBMETAL_LIBS ${LIBMETAL_LIB})
+endif (LIBMETAL_FOUND)
+
+mark_as_advanced (LIBMETAL_LIB LIBMETAL_INCLUDE_DIR LIBMETAL_LIB_DIR)

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/options.cmake

@@ -0,0 +1,73 @@
+set (PROJECT_VER_MAJOR  0)
+set (PROJECT_VER_MINOR  1)
+set (PROJECT_VER_PATCH  0)
+set (PROJECT_VER        0.1.0)
+
+if (NOT CMAKE_BUILD_TYPE)
+  set (CMAKE_BUILD_TYPE Debug)
+endif (NOT CMAKE_BUILD_TYPE)
+
+if (NOT CMAKE_INSTALL_LIBDIR)
+  set (CMAKE_INSTALL_LIBDIR "lib")
+endif (NOT CMAKE_INSTALL_LIBDIR)
+
+if (NOT CMAKE_INSTALL_BINDIR)
+  set (CMAKE_INSTALL_BINDIR "bin")
+endif (NOT CMAKE_INSTALL_BINDIR)
+
+set (_host "${CMAKE_HOST_SYSTEM_NAME}/${CMAKE_HOST_SYSTEM_PROCESSOR}")
+message ("-- Host:    ${_host}")
+
+set (_target "${CMAKE_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR}")
+message ("-- Target:  ${_target}")
+
+if (NOT DEFINED MACHINE)
+  set (MACHINE "Generic")
+endif (NOT DEFINED MACHINE)
+message ("-- Machine: ${MACHINE}")
+
+string (TOLOWER ${CMAKE_SYSTEM_NAME}      PROJECT_SYSTEM)
+string (TOUPPER ${CMAKE_SYSTEM_NAME}      PROJECT_SYSTEM_UPPER)
+string (TOLOWER ${CMAKE_SYSTEM_PROCESSOR} PROJECT_PROCESSOR)
+string (TOUPPER ${CMAKE_SYSTEM_PROCESSOR} PROJECT_PROCESSOR_UPPER)
+string (TOLOWER ${MACHINE}                PROJECT_MACHINE)
+string (TOUPPER ${MACHINE}                PROJECT_MACHINE_UPPER)
+
+# Select which components are in the openamp lib
+option (WITH_PROXY          "Build with proxy(access device controlled by other processor)" ON)
+option (WITH_APPS           "Build with sample applicaitons" OFF)
+option (WITH_PROXY_APPS     "Build with proxy sample applicaitons" OFF)
+if (WITH_APPS)
+  if (WITH_PROXY)
+    set (WITH_PROXY_APPS ON)
+  endif (WITH_PROXY)
+endif (WITH_APPS)
+
+option (WITH_VIRTIO_MASTER "Build with virtio master enabled" ON)
+option (WITH_VIRTIO_SLAVE "Build with virtio slave enabled" ON)
+
+if (NOT WITH_VIRTIO_MASTER)
+  add_definitions(-DVIRTIO_SLAVE_ONLY)
+endif (NOT WITH_VIRTIO_MASTER)
+
+if (NOT WITH_VIRTIO_SLAVE)
+  add_definitions(-DVIRTIO_MASTER_ONLY)
+endif (NOT WITH_VIRTIO_SLAVE)
+
+# Set the complication flags
+set (CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra")
+
+option (WITH_STATIC_LIB "Build with a static library" ON)
+
+if ("${PROJECT_SYSTEM}" STREQUAL "linux")
+  option (WITH_SHARED_LIB "Build with a shared library" ON)
+endif ("${PROJECT_SYSTEM}" STREQUAL "linux")
+
+if (WITH_ZEPHYR)
+  option (WITH_ZEPHYR_LIB "Build open-amp as a zephyr library" OFF)
+endif (WITH_ZEPHYR)
+
+option (WITH_LIBMETAL_FIND "Check Libmetal library can be found" ON)
+
+message ("-- C_FLAGS : ${CMAKE_C_FLAGS}")
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/platforms/cross_generic_gcc.cmake

@@ -0,0 +1,12 @@
+set (CMAKE_SYSTEM_NAME      "Generic" CACHE STRING "")
+
+include (CMakeForceCompiler)
+
+CMAKE_FORCE_C_COMPILER   ("${CROSS_PREFIX}gcc" GNU)
+CMAKE_FORCE_CXX_COMPILER ("${CROSS_PREFIX}g++" GNU)
+
+set (CMAKE_FIND_ROOT_PATH_MODE_PROGRAM	NEVER CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_LIBRARY	NEVER CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_INCLUDE	NEVER CACHE STRING "")
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/platforms/cross_linux_gcc.cmake

@@ -0,0 +1,9 @@
+set (CMAKE_SYSTEM_NAME      "Linux")
+set (CMAKE_C_COMPILER       "${CROSS_PREFIX}gcc")
+set (CMAKE_CXX_COMPILER     "${CROSS_PREFIX}g++")
+
+set (CMAKE_FIND_ROOT_PATH_MODE_PROGRAM	NEVER)
+set (CMAKE_FIND_ROOT_PATH_MODE_LIBRARY	NEVER)
+set (CMAKE_FIND_ROOT_PATH_MODE_INCLUDE	NEVER)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/platforms/zynq7_generic.cmake

@@ -0,0 +1,8 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm" CACHE STRING "")
+set (MACHINE                "zynq7" CACHE STRING "")
+set (CROSS_PREFIX           "arm-none-eabi-" CACHE STRING "")
+set (CMAKE_C_FLAGS          "-mcpu=cortex-a9 -mfpu=vfpv3 -mfloat-abi=hard" CACHE STRING "")
+
+include (cross_generic_gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/platforms/zynq7_linux.cmake

@@ -0,0 +1,6 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm")
+set (CROSS_PREFIX           "arm-xilinx-linux-gnueabi-")
+
+include (cross-linux-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/platforms/zynqmp_a53_generic.cmake

@@ -0,0 +1,6 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm64")
+set (CROSS_PREFIX           "aarch64-none-elf-")
+
+include (cross_generic_gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/platforms/zynqmp_linux.cmake

@@ -0,0 +1,7 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm64")
+set (CROSS_PREFIX           "aarch64-linux-gnu-")
+set (MACHINE                "zynqmp" CACHE STRING "")
+
+include (cross_linux_gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/platforms/zynqmp_r5_generic.cmake

@@ -0,0 +1,10 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm" CACHE STRING "")
+set (MACHINE                "zynqmp_r5" CACHE STRING "")
+set (CROSS_PREFIX           "armr5-none-eabi-" CACHE STRING "")
+
+# Xilinx SDK version earlier than 2017.2 use mfloat-abi=soft by default to generat libxil
+set (CMAKE_C_FLAGS          "-mfloat-abi=hard -mfpu=vfpv3-d16 -mcpu=cortex-r5" CACHE STRING "")
+
+include (cross_generic_gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/open-amp/cmake/syscheck.cmake

@@ -0,0 +1,13 @@
+# use "Generic" as CMAKE_SYSTEM_NAME
+
+if (WITH_ZEPHYR)
+  set (CMAKE_SYSTEM_NAME "Generic"        CACHE STRING "")
+  string (TOLOWER "Zephyr"                PROJECT_SYSTEM)
+  string (TOUPPER "Zephyr"                PROJECT_SYSTEM_UPPER)
+  if (NOT WITH_ZEPHYR_LIB)
+    include($ENV{ZEPHYR_BASE}/cmake/app/boilerplate.cmake NO_POLICY_SCOPE)
+  endif ()
+  if (CONFIG_CPU_CORTEX_M)
+    set (MACHINE "cortexm" CACHE STRING "")
+  endif (CONFIG_CPU_CORTEX_M)
+endif (WITH_ZEPHYR)