Sync inav to Gitea

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/collect.cmake

@@ -0,0 +1,36 @@
+function (collector_create name base)
+  set_property (GLOBAL PROPERTY "COLLECT_${name}_LIST")
+  set_property (GLOBAL PROPERTY "COLLECT_${name}_BASE" "${base}")
+endfunction (collector_create)
+
+function (collector_list var name)
+  get_property (_list GLOBAL PROPERTY "COLLECT_${name}_LIST")
+  set (${var} "${_list}" PARENT_SCOPE)
+endfunction (collector_list)
+
+function (collector_base var name)
+  get_property (_base GLOBAL PROPERTY "COLLECT_${name}_BASE")
+  set (${var} "${_base}" PARENT_SCOPE)
+endfunction (collector_base)
+
+function (collect name)
+  collector_base (_base ${name})
+  string(COMPARE NOTEQUAL "${_base}" "" _is_rel)
+  set (_list)
+  foreach (s IN LISTS ARGN)
+    if (_is_rel)
+      get_filename_component (s "${s}" ABSOLUTE)
+      file (RELATIVE_PATH s "${_base}" "${s}")
+    endif (_is_rel)
+    list (APPEND _list "${s}")
+  endforeach ()
+  set_property (GLOBAL APPEND PROPERTY "COLLECT_${name}_LIST" "${_list}")
+endfunction (collect)
+
+# Create global collectors
+collector_create (PROJECT_INC_DIRS    "")
+collector_create (PROJECT_LIB_DIRS    "")
+collector_create (PROJECT_LIB_DEPS    "")
+collector_create (PROJECT_HDR_TESTS "")
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/depends.cmake

@@ -0,0 +1,38 @@
+if (WITH_DOC)
+  find_package (Doxygen)
+endif (WITH_DOC)
+
+if ("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
+
+  check_include_files (stdatomic.h HAVE_STDATOMIC_H)
+  check_include_files (linux/futex.h HAVE_FUTEX_H)
+
+  find_package (HugeTLBFS)
+  if (HUGETLBFS_FOUND)
+    collect (PROJECT_INC_DIRS "${HUGETLBFS_INCLUDE_DIR}")
+    collect (PROJECT_LIB_DEPS "${HUGETLBFS_LIBRARIES}")
+    add_definitions(-DHAVE_HUGETLBFS_H)
+  endif(HUGETLBFS_FOUND)
+
+  find_package (LibSysFS REQUIRED)
+  collect (PROJECT_INC_DIRS "${LIBSYSFS_INCLUDE_DIR}")
+  collect (PROJECT_LIB_DEPS "${LIBSYSFS_LIBRARIES}")
+
+  find_package(Threads REQUIRED)
+  collect (PROJECT_LIB_DEPS "${CMAKE_THREAD_LIBS_INIT}")
+
+  find_package(LibRt REQUIRED)
+  collect (PROJECT_LIB_DEPS "${LIBRT_LIBRARIES}")
+
+else ("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
+
+  # TODO: fix for find_path() to detect stdatomic.h
+  # find_path (HAVE_STDATOMIC_H stdatomic.h)
+  set (_saved_cmake_required_flags ${CMAKE_REQUIRED_FLAGS})
+  set (CMAKE_REQUIRED_FLAGS "-c" CACHE STRING "")
+  check_include_files (stdatomic.h HAVE_STDATOMIC_H)
+  set (CMAKE_REQUIRED_FLAGS ${_saved_cmake_required_flags})
+
+endif ("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/modules/FindHugeTLBFS.cmake

@@ -0,0 +1,34 @@
+# FindHugeTLBFS
+# --------
+#
+# Find HugeTLBFS
+#
+# Find the native HugeTLBFS includes and library This module defines
+#
+# ::
+#
+#   HUGETLBFS_INCLUDE_DIR, where to find hugetlbfs.h, etc.
+#   HUGETLBFS_LIBRARIES, the libraries needed to use HugeTLBFS.
+#   HUGETLBFS_FOUND, If false, do not try to use HugeTLBFS.
+#
+# also defined, but not for general use are
+#
+# ::
+#
+#   HUGETLBFS_LIBRARY, where to find the HugeTLBFS library.
+
+find_path (HUGETLBFS_INCLUDE_DIR hugetlbfs.h)
+
+set (HUGETLBFS_NAMES ${HUGETLBFS_NAMES} hugetlbfs)
+find_library (HUGETLBFS_LIBRARY NAMES ${HUGETLBFS_NAMES})
+
+# handle the QUIETLY and REQUIRED arguments and set HUGETLBFS_FOUND to TRUE if
+# all listed variables are TRUE
+include (FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS (HUGETLBFS DEFAULT_MSG HUGETLBFS_LIBRARY HUGETLBFS_INCLUDE_DIR)
+
+if (HUGETLBFS_FOUND)
+  set (HUGETLBFS_LIBRARIES ${HUGETLBFS_LIBRARY})
+endif (HUGETLBFS_FOUND)
+
+mark_as_advanced (HUGETLBFS_LIBRARY HUGETLBFS_INCLUDE_DIR)

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/modules/FindLibRt.cmake

@@ -0,0 +1,46 @@
+#.rst:
+# FindLibRt
+# --------
+#
+# Find the native realtime includes and library.
+#
+# IMPORTED Targets
+# ^^^^^^^^^^^^^^^^
+#
+# This module defines :prop_tgt:`IMPORTED` target ``LIBRT::LIBRT``, if
+# LIBRT has been found.
+#
+# Result Variables
+# ^^^^^^^^^^^^^^^^
+#
+# This module defines the following variables:
+#
+# ::
+#
+#   LIBRT_INCLUDE_DIRS  - where to find time.h, etc.
+#   LIBRT_LIBRARIES     - List of libraries when using librt.
+#   LIBRT_FOUND         - True if realtime library found.
+#
+# Hints
+# ^^^^^
+#
+# A user may set ``LIBRT_ROOT`` to a realtime installation root to tell this
+# module where to look.
+
+find_path(LIBRT_INCLUDE_DIRS
+  NAMES time.h
+  PATHS ${LIBRT_ROOT}/include/
+)
+find_library(LIBRT_LIBRARIES rt)
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(LibRt DEFAULT_MSG LIBRT_LIBRARIES LIBRT_INCLUDE_DIRS)
+mark_as_advanced(LIBRT_INCLUDE_DIRS LIBRT_LIBRARIES)
+
+if(LIBRT_FOUND)
+    if(NOT TARGET LIBRT::LIBRT)
+      add_library(LIBRT::LIBRT UNKNOWN IMPORTED)
+      set_target_properties(LIBRT::LIBRT PROPERTIES
+        IMPORTED_LOCATION "${LIBRT_LIBRARIES}"
+        INTERFACE_INCLUDE_DIRECTORIES "${LIBRT_INCLUDE_DIRS}")
+    endif()
+endif()

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/modules/FindLibSysFS.cmake

@@ -0,0 +1,34 @@
+# FindLibSysFS
+# --------
+#
+# Find LibSysFS
+#
+# Find the native LibSysFS includes and library This module defines
+#
+# ::
+#
+#   LIBSYSFS_INCLUDE_DIR, where to find libsysfs.h, etc.
+#   LIBSYSFS_LIBRARIES, the libraries needed to use LibSysFS.
+#   LIBSYSFS_FOUND, If false, do not try to use LibSysFS.
+#
+# also defined, but not for general use are
+#
+# ::
+#
+#   LIBSYSFS_LIBRARY, where to find the LibSysFS library.
+
+find_path (LIBSYSFS_INCLUDE_DIR sysfs/libsysfs.h)
+
+set (LIBSYSFS_NAMES ${LIBSYSFS_NAMES} sysfs)
+find_library (LIBSYSFS_LIBRARY NAMES ${LIBSYSFS_NAMES})
+
+# handle the QUIETLY and REQUIRED arguments and set LIBSYSFS_FOUND to TRUE if
+# all listed variables are TRUE
+include (FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS (LIBSYSFS DEFAULT_MSG LIBSYSFS_LIBRARY LIBSYSFS_INCLUDE_DIR)
+
+if (LIBSYSFS_FOUND)
+  set (LIBSYSFS_LIBRARIES ${LIBSYSFS_LIBRARY})
+endif (LIBSYSFS_FOUND)
+
+mark_as_advanced (LIBSYSFS_LIBRARY LIBSYSFS_INCLUDE_DIR)

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/options.cmake

@@ -0,0 +1,63 @@
+set (PROJECT_VER_MAJOR  0)
+set (PROJECT_VER_MINOR  1)
+set (PROJECT_VER_PATCH  0)
+set (PROJECT_VER        0.1.0)
+
+if (NOT CMAKE_BUILD_TYPE)
+  set (CMAKE_BUILD_TYPE Debug)
+endif (NOT CMAKE_BUILD_TYPE)
+message ("-- Build type:  ${CMAKE_BUILD_TYPE}")
+
+if (NOT CMAKE_INSTALL_LIBDIR)
+  set (CMAKE_INSTALL_LIBDIR "lib")
+endif (NOT CMAKE_INSTALL_LIBDIR)
+
+if (NOT CMAKE_INSTALL_BINDIR)
+  set (CMAKE_INSTALL_BINDIR "bin")
+endif (NOT CMAKE_INSTALL_BINDIR)
+
+set (_host "${CMAKE_HOST_SYSTEM_NAME}/${CMAKE_HOST_SYSTEM_PROCESSOR}")
+message ("-- Host:    ${_host}")
+
+set (_target "${CMAKE_SYSTEM_NAME}/${CMAKE_SYSTEM_PROCESSOR}")
+message ("-- Target:  ${_target}")
+
+if (NOT DEFINED MACHINE)
+  set (MACHINE "Generic")
+endif (NOT DEFINED MACHINE)
+message ("-- Machine: ${MACHINE}")
+
+# handle if '-' in machine name
+string (REPLACE "-" "_" MACHINE ${MACHINE})
+
+if (NOT DEFINED PROJECT_SYSTEM)
+  string (TOLOWER ${CMAKE_SYSTEM_NAME}      PROJECT_SYSTEM)
+  string (TOUPPER ${CMAKE_SYSTEM_NAME}      PROJECT_SYSTEM_UPPER)
+endif (NOT DEFINED PROJECT_SYSTEM)
+
+string (TOLOWER ${CMAKE_SYSTEM_PROCESSOR} PROJECT_PROCESSOR)
+string (TOUPPER ${CMAKE_SYSTEM_PROCESSOR} PROJECT_PROCESSOR_UPPER)
+string (TOLOWER ${MACHINE}                PROJECT_MACHINE)
+string (TOUPPER ${MACHINE}                PROJECT_MACHINE_UPPER)
+
+option (WITH_STATIC_LIB "Build with a static library" ON)
+
+if ("${PROJECT_SYSTEM}" STREQUAL "linux")
+  option (WITH_SHARED_LIB "Build with a shared library" ON)
+  option (WITH_TESTS      "Install test applications" ON)
+endif ("${PROJECT_SYSTEM}" STREQUAL "linux")
+
+if (WITH_TESTS AND (${_host} STREQUAL ${_target}))
+  option (WITH_TESTS_EXEC "Run test applications during build" ON)
+endif (WITH_TESTS AND (${_host} STREQUAL ${_target}))
+
+if (WITH_ZEPHYR)
+  option (WITH_ZEPHYR_LIB "Build libmetal as a zephyr library" OFF)
+endif (WITH_ZEPHYR)
+
+option (WITH_DEFAULT_LOGGER "Build with default logger" ON)
+
+option (WITH_DOC "Build with documentation" ON)
+
+set (PROJECT_EC_FLAGS "-Wall -Werror -Wextra" CACHE STRING "")
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/cortex-m4-generic.cmake

@@ -0,0 +1,8 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm" CACHE STRING "")
+set (MACHINE "cortexm" CACHE STRING "")
+
+set (CMAKE_C_FLAGS "-mcpu=cortex-m4 -mthumb -mfloat-abi=hard -mfpu=fpv4-sp-d16 -Og -fmessage-length=0 -ffunction-sections -c" CACHE STRING "")
+
+include (cross-generic-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/cross-freertos-gcc.cmake

@@ -0,0 +1,6 @@
+# cmake 3.3.2 does not know CMAKE_SYSTEM_NAME=FreeRTOS, we set it to Generic
+include (cross-generic-gcc)
+string (TOLOWER "FreeRTOS"                PROJECT_SYSTEM)
+string (TOUPPER "FreeRTOS"                PROJECT_SYSTEM_UPPER)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/cross-generic-gcc.cmake

@@ -0,0 +1,10 @@
+set (CMAKE_SYSTEM_NAME "Generic"             CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_LIBRARY NEVER CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_INCLUDE NEVER CACHE STRING "")
+
+include (CMakeForceCompiler)
+CMAKE_FORCE_C_COMPILER   ("${CROSS_PREFIX}gcc" GNU)
+CMAKE_FORCE_CXX_COMPILER ("${CROSS_PREFIX}g++" GNU)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/cross-generic-iar.cmake

@@ -0,0 +1,10 @@
+set (CMAKE_SYSTEM_NAME "Generic"             CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_LIBRARY NEVER CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_INCLUDE NEVER CACHE STRING "")
+
+include (CMakeForceCompiler)
+CMAKE_FORCE_C_COMPILER   ("icc${CROSS_SUFFIX}" IAR)
+CMAKE_FORCE_CXX_COMPILER ("icc${CROSS_SUFFIX} --eec++" IAR)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/cross-linux-gcc.cmake

@@ -0,0 +1,8 @@
+set (CMAKE_SYSTEM_NAME  "Linux"              CACHE STRING "")
+set (CMAKE_C_COMPILER   "${CROSS_PREFIX}gcc" CACHE STRING "")
+set (CMAKE_CXX_COMPILER "${CROSS_PREFIX}g++" CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_LIBRARY NEVER CACHE STRING "")
+set (CMAKE_FIND_ROOT_PATH_MODE_INCLUDE NEVER CACHE STRING "")
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/microblaze-generic.cmake

@@ -0,0 +1,7 @@
+    set (CMAKE_SYSTEM_PROCESSOR "microblaze"              CACHE STRING "")
+    set (MACHINE "microblaze_generic" CACHE STRING "")
+    set (CROSS_PREFIX           "mb-" CACHE STRING "")
+    # These flags are for a demo. If microblaze is changed, the flags need to be changed too.
+    set (CMAKE_C_FLAGS          "-mlittle-endian  -mxl-barrel-shift -mxl-pattern-compare  \
+       -mcpu=v10.0 -mno-xl-soft-mul"   CACHE STRING "")
+    include (cross-generic-gcc)

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/template-freertos.cmake

@@ -0,0 +1,12 @@
+# Modify to match your needs.  These setttings can also be overridden at the
+# command line.  (eg. cmake -DCMAKE_C_FLAGS="-O3")
+
+set (CMAKE_SYSTEM_PROCESSOR "arm"            CACHE STRING "")
+set (MACHINE                "template"       CACHE STRING "")
+set (CROSS_PREFIX           "arm-none-eabi-" CACHE STRING "")
+
+set (CMAKE_C_FLAGS          ""               CACHE STRING "")
+
+include (cross-freertos-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/template-generic.cmake

@@ -0,0 +1,12 @@
+# Modify to match your needs.  These setttings can also be overridden at the
+# command line.  (eg. cmake -DCMAKE_C_FLAGS="-O3")
+
+set (CMAKE_SYSTEM_PROCESSOR "arm"            CACHE STRING "")
+set (MACHINE                "template"       CACHE STRING "")
+set (CROSS_PREFIX           "arm-none-eabi-" CACHE STRING "")
+
+set (CMAKE_C_FLAGS          ""               CACHE STRING "")
+
+include (cross-generic-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/zynq7-freertos.cmake

@@ -0,0 +1,9 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm"            CACHE STRING "")
+set (MACHINE                "zynq7"          CACHE STRING "")
+set (CROSS_PREFIX           "arm-none-eabi-" CACHE STRING "")
+
+set (CMAKE_C_FLAGS          "-mcpu=cortex-a9 -mfpu=vfpv3 -mfloat-abi=hard" CACHE STRING "")
+
+include (cross-freertos-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/zynq7-generic-iar.cmake

@@ -0,0 +1,5 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm" CACHE STRING "")
+set (CROSS_SUFFIX           "arm" CACHE STRING "")
+include (cross-generic-iar)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/zynq7-generic.cmake

@@ -0,0 +1,9 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm"            CACHE STRING "")
+set (MACHINE                "zynq7"          CACHE STRING "")
+set (CROSS_PREFIX           "arm-none-eabi-" CACHE STRING "")
+
+set (CMAKE_C_FLAGS          "-mcpu=cortex-a9 -mfpu=vfpv3 -mfloat-abi=hard" CACHE STRING "")
+
+include (cross-generic-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/zynq7-linux.cmake

@@ -0,0 +1,5 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm"                       CACHE STRING "")
+set (CROSS_PREFIX           "arm-xilinx-linux-gnueabi-" CACHE STRING "")
+include (cross-linux-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/zynqmp-a53-freertos.cmake

@@ -0,0 +1,8 @@
+set (CMAKE_SYSTEM_PROCESSOR "aarch64"           CACHE STRING "")
+set (MACHINE                "zynqmp_a53"        CACHE STRING "")
+set (CROSS_PREFIX           "aarch64-none-elf-" CACHE STRING "")
+set (CMAKE_C_FLAGS          ""                  CACHE STRING "")
+
+include (cross-freertos-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/zynqmp-a53-generic.cmake

@@ -0,0 +1,8 @@
+set (CMAKE_SYSTEM_PROCESSOR "aarch64"           CACHE STRING "")
+set (MACHINE                "zynqmp_a53"        CACHE STRING "")
+set (CROSS_PREFIX           "aarch64-none-elf-" CACHE STRING "")
+set (CMAKE_C_FLAGS          ""                  CACHE STRING "")
+
+include (cross-generic-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/zynqmp-linux.cmake

@@ -0,0 +1,5 @@
+set (CMAKE_SYSTEM_PROCESSOR "aarch64"            CACHE STRING "")
+set (CROSS_PREFIX           "aarch64-linux-gnu-" CACHE STRING "")
+include (cross-linux-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/zynqmp-r5-freertos.cmake

@@ -0,0 +1,8 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm"              CACHE STRING "")
+set (MACHINE                "zynqmp_r5"        CACHE STRING "")
+set (CROSS_PREFIX           "armr5-none-eabi-" CACHE STRING "")
+set (CMAKE_C_FLAGS          "-mfloat-abi=soft -mcpu=cortex-r5" CACHE STRING "")
+
+include (cross-freertos-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/platforms/zynqmp-r5-generic.cmake

@@ -0,0 +1,10 @@
+set (CMAKE_SYSTEM_PROCESSOR "arm"              CACHE STRING "")
+set (MACHINE                "zynqmp_r5"        CACHE STRING "")
+set (CROSS_PREFIX           "armr5-none-eabi-" CACHE STRING "")
+
+# Xilinx SDK version earlier than 2017.2 use mfloat-abi=soft by default to generat libxil
+set (CMAKE_C_FLAGS          "-mfloat-abi=hard -mfpu=vfpv3-d16 -mcpu=cortex-r5" CACHE STRING "")
+
+include (cross-generic-gcc)
+
+# vim: expandtab:ts=2:sw=2:smartindent

lib/main/STM32H7/Middlewares/Third_Party/OpenAMP/libmetal/cmake/syscheck.cmake

@@ -0,0 +1,13 @@
+# use "Generic" as CMAKE_SYSTEM_NAME
+
+if (WITH_ZEPHYR)
+  set (CMAKE_SYSTEM_NAME "Generic"             CACHE STRING "")
+  string (TOLOWER "Zephyr"                PROJECT_SYSTEM)
+  string (TOUPPER "Zephyr"                PROJECT_SYSTEM_UPPER)
+  if (NOT WITH_ZEPHYR_LIB)
+    include($ENV{ZEPHYR_BASE}/cmake/app/boilerplate.cmake NO_POLICY_SCOPE)
+  endif()
+  if (CONFIG_CPU_CORTEX_M)
+    set (MACHINE "cortexm" CACHE STRING "")
+  endif (CONFIG_CPU_CORTEX_M)
+endif (WITH_ZEPHYR)