Sync edgetx to Gitea

cmake/toolchain/arm-none-eabi.cmake

@@ -0,0 +1,53 @@
+# arm-none-eabi toolchain
+set(CMAKE_SYSTEM_NAME Generic)
+set(CMAKE_SYSTEM_PROCESSOR arm)
+set(CMAKE_CXX_STANDARD 17)
+
+set(CMAKE_TRY_COMPILE_TARGET_TYPE STATIC_LIBRARY)
+
+if(MINGW OR WIN32)
+  set(EXE_SUFFIX ".exe")
+  set(CMAKE_OBJECT_PATH_MAX 200)
+endif()
+
+if(ARM_TOOLCHAIN_DIR)
+  cmake_path(SET ARM_TOOLCHAIN_DIR NORMALIZE ${ARM_TOOLCHAIN_DIR})
+  set(ARM_TOOLCHAIN_DIR "${ARM_TOOLCHAIN_DIR}/")
+endif()
+
+set(CMAKE_AR           ${ARM_TOOLCHAIN_DIR}arm-none-eabi-ar${EXE_SUFFIX})
+set(CMAKE_ASM_COMPILER ${ARM_TOOLCHAIN_DIR}arm-none-eabi-gcc${EXE_SUFFIX})
+set(CMAKE_C_COMPILER   ${ARM_TOOLCHAIN_DIR}arm-none-eabi-gcc${EXE_SUFFIX})
+set(CMAKE_CXX_COMPILER ${ARM_TOOLCHAIN_DIR}arm-none-eabi-g++${EXE_SUFFIX})
+set(CMAKE_LINKER       ${ARM_TOOLCHAIN_DIR}arm-none-eabi-ld${EXE_SUFFIX})
+set(CMAKE_OBJCOPY      ${ARM_TOOLCHAIN_DIR}arm-none-eabi-objcopy${EXE_SUFFIX} CACHE INTERNAL "")
+set(CMAKE_RANLIB       ${ARM_TOOLCHAIN_DIR}arm-none-eabi-ranlib${EXE_SUFFIX} CACHE INTERNAL "")
+set(CMAKE_SIZE_UTIL    ${ARM_TOOLCHAIN_DIR}arm-none-eabi-size${EXE_SUFFIX} CACHE INTERNAL "")
+set(CMAKE_STRIP        ${ARM_TOOLCHAIN_DIR}arm-none-eabi-strip${EXE_SUFFIX} CACHE INTERNAL "")
+set(CMAKE_GCOV         ${ARM_TOOLCHAIN_DIR}arm-none-eabi-gcov${EXE_SUFFIX} CACHE INTERNAL "")
+
+# Generate .elf files
+set(CMAKE_EXECUTABLE_SUFFIX ".elf")
+set(CMAKE_EXECUTABLE_SUFFIX_C ".elf")
+set(CMAKE_EXECUTABLE_SUFFIX_CXX ".elf")
+
+# Default C compiler flags
+set(CMAKE_C_FLAGS_DEBUG_INIT "-g3 -Og -Wall -pedantic -DDEBUG")
+set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG_INIT}" CACHE STRING "" FORCE)
+set(CMAKE_C_FLAGS_RELEASE_INIT "-O3 -Wall")
+set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE_INIT}" CACHE STRING "" FORCE)
+
+# Default C++ compiler flags
+set(CMAKE_CXX_FLAGS_DEBUG_INIT "-g3 -Og -Wall -pedantic -DDEBUG")
+set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG_INIT}" CACHE STRING "" FORCE)
+set(CMAKE_CXX_FLAGS_RELEASE_INIT "-O3 -Wall")
+set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE_INIT}" CACHE STRING "" FORCE)
+
+# customize linker command
+set(CMAKE_EXE_LINKER_FLAGS "")
+set(CMAKE_C_LINK_EXECUTABLE "<CMAKE_C_COMPILER> <FLAGS> <LINK_FLAGS> <OBJECTS>  -o <TARGET> <LINK_LIBRARIES>")
+set(CMAKE_CXX_LINK_EXECUTABLE "<CMAKE_CXX_COMPILER> <FLAGS> <LINK_FLAGS> <OBJECTS>  -o <TARGET> <LINK_LIBRARIES>")
+
+set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
+set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
+set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)

cmake/toolchain/native.cmake

@@ -0,0 +1,15 @@
+# Native toolchain
+set(CMAKE_CXX_STANDARD 17)
+
+if(APPLE)
+  set(CMAKE_C_FLAGS "-Wno-deprecated-declarations")
+  set(CMAKE_CXX_FLAGS "-Wno-deprecated-declarations")
+  set(CMAKE_C_FLAGS_DEBUG "-Wno-deprecated-declarations")
+  set(CMAKE_CXX_FLAGS_DEBUG "-Wno-deprecated-declarations")
+endif()
+
+set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-address-of-packed-member -Wno-deprecated-declarations")
+
+if(MINGW OR WIN32)
+  set(CMAKE_OBJECT_PATH_MAX 200)
+endif()

cmake/toolchain/wasi-threads.cmake

@@ -0,0 +1,20 @@
+# Wrapper around wasi-sdk's pthread toolchain that uses the non-deprecated
+# wasm32-wasip1-threads triple (compatible with SDK 25+).
+
+# Propagate WASI_SDK_PREFIX into try_compile sub-projects (used during ABI detection)
+list(APPEND CMAKE_TRY_COMPILE_PLATFORM_VARIABLES WASI_SDK_PREFIX)
+
+if(NOT WASI_SDK_PREFIX)
+  if(DEFINED ENV{WASI_SDK_PATH})
+    set(WASI_SDK_PREFIX $ENV{WASI_SDK_PATH})
+  elseif(EXISTS "/opt/wasi-sdk")
+    set(WASI_SDK_PREFIX "/opt/wasi-sdk")
+  endif()
+endif()
+
+include(${WASI_SDK_PREFIX}/share/cmake/wasi-sdk-pthread.cmake)
+
+set(triple wasm32-wasip1-threads)
+set(CMAKE_C_COMPILER_TARGET ${triple})
+set(CMAKE_CXX_COMPILER_TARGET ${triple})
+set(CMAKE_ASM_COMPILER_TARGET ${triple})